' File Version: 1.2
' As Of: 2/13/2026
' Latest Change: Updated ThisOutlookSession  - added Sub junkItems_ItemAdd() and necessary syntax to automate managing Junk email folder.
'
' Version: 1.0 - 2/1/2026 - Initial spam filter version.

Option Explicit

Private WithEvents inboxItems As Outlook.Items
Private WithEvents junkItems As Outlook.Items

Private Sub Application_Startup()
    
  Dim outlookApp As Outlook.Application
  Dim objectNS As Outlook.NameSpace
  
  Set outlookApp = Outlook.Application
  Set objectNS = outlookApp.GetNamespace("MAPI")
  Set inboxItems = objectNS.GetDefaultFolder(olFolderInbox).Items
  Set junkItems = objectNS.GetDefaultFolder(olFolderJunk).Items
 
End Sub

Private Sub inboxItems_ItemAdd(ByVal Item As Object)
    On Error GoTo ErrorHandler
    
    If TypeName(Item) = "MailItem" Then
        Call ProcessSpamEmails
    End If
    
ExitSub:
    Exit Sub
    
ErrorHandler:
    MsgBox Err.Number & " - " & Err.Description
    Resume ExitSub
    
End Sub

Private Sub junkItems_ItemAdd(ByVal Item As Object)
    On Error GoTo ErrorHandler

    If TypeName(Item) = "MailItem" Then
        Call MoveJunk2Inbox
    End If
    
ExitSub:
    Exit Sub
    
ErrorHandler:
    MsgBox Err.Number & " - " & Err.Description
    Resume ExitSub
    
End Sub